***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 26, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3434-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     90.77
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=5.50  VTO=0.9  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=2.5e10  gamma=0.3)
Rd     d1    d2    195m TC=3.3m
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=22  TBV1=5.452e-4   CJO=5.950e-12  M=2.683e-1  VJ=3.905e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=3.088e-14  N=1.209  RS=12.04u  EG=1.45  TT=20n ikf=22.660)
Rdiode  d1  21    1.0070e-1 TC=8.6m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.282E-11
.MODEL     DGD    D(M=5.942e-1   CJO=4.282e-11   VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.08907e-11
.ENDS
*$
